ポリラインの値をガウス関数で平滑化する

//
// upベクトルにブラーを掛ける
// カーブに沿った距離でガウスブラーをかける
// Run Over: Points
//
float blurRadius = `chs("../blurDist")`; // ブラーする距離（範囲）
int num = 10; // サンプルするポイント数
float step = blurRadius / (float)num;
int prim = pointprims(0, @ptnum)[0];
float curveLength = primintrinsic(0, "measuredperimeter", prim);

vector weighted_up = {0,0,0};
float total_weight = 0;

// ポイントのUV値を取得する
vector pos = point(0, "P", @ptnum);
int index;
vector uv;
xyzdist(0, pos, index, uv);

// マイナス方向
for(int i = 0; i < num; i++)
{
    // 端はクランプする
    float prev_u = clamp(uv.x - (step * i / curveLength), 0, 1);
    vector pt_up = primuv(0, "up", index, set(prev_u, 0));
    
    // 距離による重み（ガウシアン）
    float dist = step * i;
    float weight = exp(-pow(dist / blurRadius, 2));
    weighted_up += pt_up * weight;
    total_weight += weight;
}

// プラス方向
for(int i = 1; i < num; i++)
{
    // 端はクランプする
    float next_u = clamp(uv.x + (step * i / curveLength), 0, 1);
    vector pt_up = primuv(0, "up", index, set(next_u, 0));
    
    // 距離による重み（ガウシアン）
    float dist = step * i;
    float weight = exp(-pow(dist / blurRadius, 2));
    weighted_up += pt_up * weight;
    total_weight += weight;
}

if(total_weight > 0) {
    v@up = normalize(weighted_up / total_weight);
}

float weight = exp(-pow(dist / blurRadius, 2));