Polypath SOPのVEX解説

void sortedRemoveDuplicates(int a[]) {
    int n = len(a);
    if (n <= 1) {
        return;
    }
    int prev = a[0];
    int desti = 1;
    for (int i = 1; i < n; ++i) {
        if (a[i] != prev) {
            if (i != desti) {
                a[desti] = a[i];
            }
            ++desti;
            prev = a[i];
        }
    }
    resize(a, desti);
}
 
int traceEdges(const int ifirst; const int inext; int path[]) {
    int prev = ifirst;
    int next = inext;
    while (1) { // 無限ループ
        int adj[] = neighbours(0,next);
        adj = sort(adj);
        sortedRemoveDuplicates(adj); // 重複の解消
         
        // Ignore any self-loops or back edges
        removevalue(adj, next); // 配列から値を削除する
        removevalue(adj, prev);
         
        int n = len(adj);
        if (n != 1) { // 隣接ポイント数が0、または複数の場合は端のポイントなので終わらせる
            // end point: successful path!
            break;
        }
         
        int other = adj[0];
         
        // If other is a lower point number, it
        // "owns" this path.
        if (other < ifirst) { // 開始ポイントより番号が小さい場合は終了させる
            return 0;
        }
         
        // Add other to the path
        append(path, other);
        prev = next;
        next = other;
         
        // If loops back to original, stop and indicate it.
        if (other == ifirst) { // 探索ポイントが最初の番号だった場合、ループしているとみなす
            return 2;
        }
    }
    return 1; // Breakで抜けた場合は成功フラグ
}
 
int adj[] = neighbours(0,@ptnum);
 
adj = sort(adj); // 昇順に並べ替え。例{0, 3, 7, 12}
sortedRemoveDuplicates(adj);
 
// Ignore any self-loops
removevalue(adj, @ptnum);
 
int n = len(adj);
 
if (n == 0) { // 隣接ポイントがないなら終了
    return;
}
 
// Only the lowest-numbered points are designated
// to trace out the paths.
if (n == 1 && @ptnum > adj[0]) { // 隣接ポイントがひとつで、開始ポイントより小さければ終了
    return;
}
if (n == 2 && @ptnum > min(adj[0],adj[1])) { // 隣接ポイントの小さい方の値が開始ポイントより小さければ終了
    return;
}
 
// If larger than largest neighbour, can't be min
// on any path.
if (@ptnum > adj[n-1]) { // 一番大きい隣接ポイントより開始ポイントが大きければ終了
    return;
}
 
// Need to trace 2 paths if degree is exactly 2
if (n == 2) {
    int path0[] = array(adj[0]);
    int path1[];
    int success = traceEdges(@ptnum, adj[0], path0);
    if (success == 0) {
        return;
    }
    // 2 indicates a loop, so only one path
    int loop = (success == 2);
    if (!loop) { // ループしてない場合
        path1 = array(adj[1]);
        success = traceEdges(@ptnum, adj[1], path1);
        if (success == 0) {
            return;
        }
    }
     
    int closed = chi("../closeloops") && loop;
    int prim = addprim(geoself(), closed ? "poly" : "polyline");
    int n0 = len(path0)-closed;
    int n1 = len(path1);
    for (int i = n1-1; i >= 0; --i) {
        addvertex(geoself(), prim, path1[i]);
    }
    addvertex(geoself(), prim, @ptnum);
    for (int i = 0; i < n0; ++i) {
        addvertex(geoself(), prim, path0[i]);
    }
}
else {
    for (int j = 0; j < n; ++j) {
        // Only the lowest-numbered points are designated
        // to trace out the paths.
        if (adj[j] < @ptnum) { // 隣接ポイント番号が始点より小さかったら
            continue; // 処理を終了して次のループへ
        }
        int path[] = array(adj[j]);
        int success = traceEdges(@ptnum, adj[j], path);
        if (success == 0) { // ポイントをトレースして始点より小さい値が出た場合
            continue; // 処理を終了して次のループへ
        }
        int npath = len(path);
         
        // 2 indicates a loop, so another neighbour must
        // be removed
        if (success == 2) { // ループしていたらForループから候補を削除する
            int other = path[npath-2];
            removevalue(adj, other);
            --n;
        }
        int prim = addprim(geoself(), "polyline"); // ループしているポリラインを生成
        addvertex(geoself(), prim, @ptnum);
        for (int i = 0; i < npath; ++i) {
            addvertex(geoself(), prim, path[i]);
        }
    }
}